# Update: Popolon <popolon@popolon.org>
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Benoît Allard <benoit dot allard at gmx dot de>
# Contributor: killruana <killruana@gmail.com>

pkgname=yosys
pkgver=0.18
pkgrel=1
pkgdesc='A framework for RTL synthesis'
arch=('x86_64' 'armv7h' 'aarch64' 'riscv32' 'riscv64')
url='http://yosyshq.net/yosys/'
license=('custom:ISC')
depends=('abc' 'bash' 'boost-libs' 'tcl' 'libffi' 'python' 'protobuf')
makedepends=('boost')
checkdepends=('iverilog')
optdepends=('graphviz: Schematics display support'
            'xdot: Display netlists')
source=("https://github.com/YosysHQ/yosys/archive/refs/tags/$pkgname-$pkgver.tar.gz")
sha512sums=('5a59b65ec5df33bb1767383b580f5e08345d601dd9a8197f4cc96e9a5fff91b87f47090a6a4e9e5552e1691dbacc4ff74d53837ade3fadab7a0aa085004b51e6')

_make() {
    make \
        PREFIX="/usr" \
        CONFIG=gcc \
        ENABLE_TCL=1 \
        ENABLE_ABC=1 \
        ENABLE_GLOB=1 \
        ENABLE_PLUGINS=1 \
        ENABLE_LIBYOSYS=1 \
        ENABLE_PROTOBUF=1 \
        ENABLE_ZLIB=1 \
        ENABLE_PYOSYS=1 \
        ABCEXTERNAL=abc \
        BOOST_PYTHON_LIB="-lpython3.10 -lboost_python310" $@
}

build() {
    cd $pkgname-$pkgname-$pkgver
    _make
}

check() {
    cd $pkgname-$pkgname-$pkgver
    _make test
}

package() {
    cd $pkgname-$pkgname-$pkgver
    _make DESTDIR="$pkgdir" PYTHON_PREFIX="$pkgdir/usr" install

    install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname/
}